Ravel

From APL Wiki
Jump to navigation Jump to search
,

Ravel (,) is a primitive function introduced in APL\360 which returns the ravel of an array. In the APL array model, an array's ravel is the vector containing all its elements in ravel order. It is equivalent to reshaping an array using its bound for the new shape. Reshaping the ravel using the original array's shape restores that array.

In some APLs an axis may be specified for Ravel in order to combine only some axes of an array, or insert a length-1 axis.

The name "ravel" references the process of undoing woven or knitted fabric, thus removing its structure and rendering it linear.

Examples

You can use ravel to squash a matrix down to one dimension. The elements are listed in reading order—left to right, top to bottom. 

      ⎕←x ← 3 4⍴⍳12            ⍝ A matrix
1  2  3  4
5  6  7  8
9 10 11 12
      ,x                      ⍝ Its ravel
1 2 3 4 5 6 7 8 9 10 11 12
      ⍴,x                     ⍝ The shape is the total number of elements
12
      (,×/⍴x) ≡ ⍴,x           ⍝ Or the product of the original shape
1

Ravelling a scalar yields a singleton vector. 

      ,3
3
      3 ≡ ,3                  ⍝ Not the same
0
      ⍴,3                     ⍝ It's now a vector
1

String notation cannot produce a single-character string since it produces a scalar character instead. Using Ravel on a list of characters in quotes ensures it will be a vector of characters. 

      ≢⍴ 'a'                  ⍝ Scalar character
0
      ≢⍴ ,'a'                 ⍝ String
1

With axis

Axis specification may accept either a vector of two or more adjacent axis indices, or a single non-integer value. If multiple axes are given, they are merged into one axis whose length is the product of their lengths. If only one value is given, a new axis of length 1 is inserted in the indicated "gap" between axes. 

      ⍴ ,[2 3] 5 4 3 2⍴0
5 12 2
      ⍴ ,[2.5] 5 4 3 2⍴0
5 4 1 3 2
Works in: Dyalog APL

Description

The ravel of an array A has shape ,×/⍴A and shares elements with A. Thus Ravel may be modelled as a reshaping function {(×/⍴⍵)⍴⍵}. The element with index vector I is moved to index (⍴A)⊥I in index origin 0, or ⎕IO+(⍴A)⊥I-⎕IO in arbitrary index origin.

As with any reshaping, the result of Ravel has the same prototype as the argument.

History

Ravel was present in the first version of APL\360[1] and has been included in every APL since.

See also

External links

Lessons

Documentation

  • BQN (as Deshape)

References

  1. ↑ Falkoff, A.D., and K.E. Iverson. "The APL\360 Terminal System". Research Report RC-1922, IBM, 1967-10-16.


APL features [edit]
Built-ins Primitives (functions, operators) ∙ Quad name
Array model Shape ∙ Rank ∙ Depth ∙ Bound ∙ Index (Indexing) ∙ Axis ∙ Ravel ∙ Ravel order ∙ Element ∙ Scalar ∙ Vector ∙ Matrix ∙ Simple scalar ∙ Simple array ∙ Nested array ∙ Cell ∙ Major cell ∙ Subarray ∙ Empty array ∙ Prototype
Data types Number (Boolean, Complex number) ∙ Character (String) ∙ Box ∙ Namespace ∙ Function array
Concepts and paradigms Conformability (Scalar extension, Leading axis agreement) ∙ Scalar function (Pervasion) ∙ Identity element ∙ Complex floor ∙ Array ordering (Total) ∙ Tacit programming (Function composition, Close composition) ∙ Glyph ∙ Leading axis theory ∙ Major cell search ∙ First-class function
Errors LIMIT ERROR ∙ RANK ERROR ∙ SYNTAX ERROR ∙ DOMAIN ERROR ∙ LENGTH ERROR ∙ INDEX ERROR ∙ VALUE ERROR ∙ EVOLUTION ERROR
APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=Ravel&oldid=10939’