Floor

From APL Wiki
Jump to navigation Jump to search
⌊

Floor (⌊) is a monadic scalar function that gives the floor of a real number, that is, the greatest integer tolerantly[1] less than or equal to the given value. This operation is also known as integral part, entier, and round down. Floor shares the glyph ⌊ with the dyadic arithmetic function Minimum. Traditional mathematics derives its notation and name for floor from APL.

Examples

Floor rounds down the given numbers to the nearest integers. 

      ⌊2 2.8 ¯2 ¯2.8
2 2 ¯2 ¯3

Rounding to the nearest integer (rounding up on half) can be achieved by adding 0.5 before applying Floor. 

      ⌊0.5+2 2.3 2.5 2.8
2 2 3 3

Integral quotient of division can be found with division followed by Floor. 

      ⌊10 20 30÷3
3 6 10

Properties

The floor of any real number is an integer.

Floor is affected by comparison tolerance. If the given number is tolerantly equal to its ceiling, it is rounded to that number instead. 

      ⎕PP←16
      ⎕←v←1+0.6×⎕CTׯ2 ¯1 0
0.999999999999988 0.999999999999994 1
      ⌊v
0 1 1

Model

Floor can very easily be modelled using residue like: 

      model←{⍵-1|⍵}

To model it without using residue, because residue uses floor under the hood, approaches like converting to strings and then stripping the decimal component or converting to binary and stripping the decimal component can be used. 

      model←{
        ⎕pp←34                  ⍝ set to max as we are using strings, the execute and format primitives round the number to the ⎕pp value
        dotPos←⍸,'.'⍷⍕⍵         ⍝ convert num to string and get the position of the decimal point
        int←⍎(⍕⍵)↑⍨¯1+dotPos    ⍝ strip integer based on the decimal point
        int-(⍵<0)∧(~0∊⍴dotPos)  ⍝ Subtract 1 only when negative+non int component exists. eg: ¯123.32→¯124
    }

Converting to the exponent/scientific notation (123E¯2) and then using the exponent and mantissa to strip the decimal points can be used.

Warning: However, the method present here has issues dealing with larger values due to the loss in precision because of the ⍎ operator. 

      model←{
        fmt←{⎕FR≡1287:¯33⍕⍵ ⋄ ¯16⍕⍵}⍵
        (m e)←'E'(≠⊆⊢)fmt
        en←⍎e
        diff←-(⍵<0)∧('.'∊⍕⍵)
        en<0:diff+0
        m↑⍨←3+(⍵<0)+en
        diff+⍎m,'E',e
    }

Other approaches could include writing a hungry loop to evaluate the closest integer value and evaluate from there.

Complex floor

Main article: Complex Floor

Eugene McDonnell designed the domain extension of Floor to complex numbers.[2] Complex floor maps every complex number to a Gaussian integer, a complex number whose real and imaginary parts are integers. It has an important property that the magnitude of difference between any complex number Z and its floor is less than 1. This extension is currently implemented in Dyalog APL, J, and NARS2000, and is internally used to implement complex ceiling, residue, and GCD. 

      v←1.8J2.5 2.2J2.5 2.5J2.2 2.5J1.8
      ⌊v
2J2 2J2 2J2 2J2
      1>|v-⌊v
1 1 1 1
Works in: Dyalog APL

External links

Documentation

References

  1. ↑ Bernecky, Robert. "Comparison Tolerance". Sharp APL Technical Notes. 1977-06-10;.
  2. ↑ McDonnell, Eugene. "Complex Floor".
APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=Floor&oldid=10610’