Type

From APL Wiki
Jump to navigation Jump to search
∊ ⊤ ⍷

Type (∊, ⊤, ⍷) is a monadic scalar function which in the nested array model gives information about the type and structure of its argument array's elements. In normal cases, the result is identical to the argument, with all numbers replaced by zeros and all characters replaced by spaces, and the substitution is done recursively.

Support

Few dialects have Type as a primitive function. APL2 IUP had it,[1] and thus Dyalog APL originally supported it too. However, by the time IBM released APL2, ∊ (as in prototypical element) was repurposed for Enlist. Thus, Dyalog left the Type meaning in place only when migration level is 0, while setting it to 1 or higher follows IBM's replacement meaning. NARS2000 uses monadic ⊤ (resembling the Latin letter T for Type), which it inherited from NARS. Extended Dyalog APL uses monadic ⍷ with the underscore indicating functionality of the corresponding non-underscored glyph from a non-default migration level.[2]

However, in all dialects that support nested arrays, the type can be determined by enclosing/boxing the array in an empty array, and then coercing out a fill value. Since the array prototype is used as fill element, the resulting array will be the type of the original array: 

      ↑ 0 ⍴ ⊂ 1 2 'ab'
┌─┬─┬──┐
│0│0│  │
└─┴─┴──┘
Works in: Dyalog APL with migration level≥2, APL2, APLX
      ⊃ 0 ⍴ ⊂ 1 2 'ab'
┌─┬─┬──┐
│0│0│  │
└─┴─┴──┘
Works in: Dyalog APL with migration level=1

Additional types

Dyalog APL has additional data types, besides for the traditional numeric, character, and nested ones. Nulls and Object Representations are their own type, while instances of objects with niladic constructor (or no constructors) cause the creation of new instances of the same class. Other objects, namely namespaces and classes with constructors but no niladic constructor, cause a NONCE ERROR.

Examples

Type can be used to construct universal utilities that adapt to the type of data given as argument. For example: 

      Null  ← ≡∘∊⍨  ⍝ Indicate empty or all blank and/or zero
      Nil   ← ∊∘∊⍨  ⍝ Indicates null items
      Clean ← ~∘∊⍨  ⍝ Without null items
      Split ← (⊢⊆⍨∊≢¨⊢)  ⍝ Split on null items
      data  ← 'Hello' '  ' 'World' ⎕NULL (2 7 1 8) (3 1 4 1 5) (0 0 0) (0 0 7) 

      Null 2⊃data
1
      Null 3⊃data
0
      Nil data
0 1 0 1 0 0 1 0
      Clean data
┌─────┬─────┬───────┬─────────┬─────┐
│Hello│World│2 7 1 8│3 1 4 1 5│0 0 7│
└─────┴─────┴───────┴─────────┴─────┘
      Split data
┌───────┬───────┬───────────────────┬───────┐
│┌─────┐│┌─────┐│┌───────┬─────────┐│┌─────┐│
││Hello│││World│││2 7 1 8│3 1 4 1 5│││0 0 7││
│└─────┘│└─────┘│└───────┴─────────┘│└─────┘│
└───────┴───────┴───────────────────┴───────┘
Works in: Dyalog APL with migration level=0

External links

Documentation

References

  1. ↑ Graham, Alan. Idioms and Problem Solving Techniques in APL2; Appendix - APL2 Idiom List: 9. Type. APL86.
  2. ↑ Partition is ⊆ with migration level≤2 while the original glyph is ⊂ as with migration level 3. Dyalog Language Reference Guide: Left Shoe.
APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=Type&oldid=10082’