Materialise

From APL Wiki
Jump to navigation Jump to search
⌷

Materialise (⌷) is a monadic primitive function which tries to cast the argument (which can be any object) into an APL array. If the argument is already an array, it is returned unmodified. It is only available in Dyalog APL, which supports classes and .NET objects. Materialise shares its glyph ⌷ with Index.

Examples

Dyalog APL allows the user to define a class, which looks like the following: 

:Class cl
    :Property Default thing
    :Access Public Shared
        ∇ r←get
          r←3 1 4 1 4
        ∇
    :EndProperty
:EndClass
Works in: Dyalog APL

If one property is declared as default, Materialise returns the value of the default property. 

      ⊢cl  ⍝ It is an object
#.cl
      ⌷cl  ⍝ ⌷ casts cl to an array by getting the default property
3 1 4 1 4
      cl.thing  ⍝ Actual effect of the line above
3 1 4 1 4
Works in: Dyalog APL

Materialise can also be used on a .NET collection, which returns the underlying array of data. 

      ba←⎕NEW System.Collections.BitArray(⊂1 0 1 1 0)
      ⍬≡⍴ba  ⍝ ba itself is a scalar object
1
      ⍴⌷ba  ⍝ but it is actually a container of 5 values
5
Works in: Dyalog APL

Materialise is the same as Identity for APL arrays. 

      (⌷≡⊢) 1 2 3 4 5
1
Works in: Dyalog APL

External links

Tutorials

Documentation


APL built-ins [edit]
Primitive functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Primitive operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut (J)
Quad names
Arrays Index origin ∙ Migration level ∙ Atomic vector
Functions Name class ∙ Case convert ∙ Unicode convert
Operators Search ∙ Replace
Retrieved from ‘https://aplwiki.com/index.php?title=Materialise&oldid=9349’