Each

¨

Each (¨) is a primitive monadic operator which applies its operand to each element of the arguments, and returns an array whose elements are the results. If two arguments are given, their elements are matched using conformability rules.

Each is defined only in nested APLs. Some flat APLs obtain analogous functionality by using an Under operator with close composition along with the rank-0 function Disclose (or Unbox). In SHARP APL this is written f¨>. In J it is f&.>.

Each differs from the Rank operator with rank 0 in that the operand arguments and results are not enclosed. As the elements of a nested array they need not be scalar.

For example,

      1,1 2 3 ⍝ join 1 with 1 2 3
1 1 2 3
      1,¨1 2 3 ⍝ join 1 with each element of 1 2 3
┌───┬───┬───┐
│1 1│1 2│1 3│
└───┴───┴───┘

Note that this operator has no effect on scalar functions, since these functions map to each array elements by default.

For example, both expression below has the same meaning, since + is a scalar function.

      1 + 1 2 3 4
2 3 4 5
      1 +¨ 1 2 3 4
2 3 4 5

External links

Lessons

• APL Cultivation

Documentation

• Dyalog (monadic operand), Dyalog (dyadic operand)
• APLX