Drop

From APL Wiki
Revision as of 21:04, 10 September 2022 by Adám Brudzewsky (talk | contribs) (Text replacement - "<source" to "<syntaxhighlight")
Jump to navigation Jump to search

Drop (↓) is a primitive function which removes part of each axis of an array. The removed portions are exactly those that Take would include in its result. Drop is subject to the same extensions as Take, and a detailed description of those extensions and their history is given in that article rather than this one. Unlike Take, Drop never uses fill elements and the result is always a subarray of the argument.

Examples

Use Drop to remove leading or trailing elements from a vector: <syntaxhighlight lang=apl> 

     3 ↓ 5 4 3 2 1

2 1 

     ¯3 ↓ 5 4 3 2 1

5 4 </source>

Removing more elements than the length of the axis gives an empty result: <syntaxhighlight lang=apl> 

     ¯8 ↓ 5 4 3 2 1

</source>

Works in: Dyalog APL, ngn/apl

When the right argument is a multidimensional array, one element from the left argument is used for each axis. In a language that supports axis specification for Take, or allows a short left argument, you can specify drop amounts for only some axes: other axes will remain unchanged. <syntaxhighlight lang=apl> 

     2 3 ↓ ⍳4 5

┌───┬───┐ │3 4│3 5│ ├───┼───┤ │4 4│4 5│ └───┴───┘ </source>

Description

The arguments to Drop must be valid arguments to Take, and elements of the left argument are matched to axes of the right in the same way. Like Take, the left argument is subject to scalar rank extension, and in some APLs the right is as well.

Each axis with a matching left argument element <syntaxhighlight lang=apl inline>d</source> is modified to remove <syntaxhighlight lang=apl inline>|d</source> indices, or all of them if <syntaxhighlight lang=apl inline>|d</source> is larger than the length of the axis. Indices are removed starting from the beginning if <syntaxhighlight lang=apl inline>d</source> is positive and starting from the end if it is negative (if <syntaxhighlight lang=apl inline>d</source> is 0, then no indices are removed). Equivalently, for an axis of length <syntaxhighlight lang=apl inline>l</source>, <syntaxhighlight lang=apl inline>l-l⌊|d</source> axes are retained—not dropped—from the axis starting from the opposite side: the end if <syntaxhighlight lang=apl inline>d</source> is positive and the beginning otherwise. If <syntaxhighlight lang=apl inline>|d</source> is greater than or equal to <syntaxhighlight lang=apl inline>l</source> for any axis, then the result is empty and shares a prototype with the argument.

APL Model

Drop can be modelled using Take with a complementary length: <syntaxhighlight lang=apl> Drop ← { 

   s ← ⍴⍵
   s ,← ((0=≢s)×≢⍺)⍴1          ⍝ Scalar rank extension
   s ← (≢⍺)↑s                  ⍝ SHARP APL extension
   ((sׯ1*⍺>0) + (-s)⌈s⌊⍺) ↑ ⍵

} </source> The code works by modifying the left argument using the right argument's shape. First, the shape is used to restrict the left argument's range (<syntaxhighlight lang=apl inline>(-s)⌈s⌊⍺</source>) so that the maximum number of indices dropped is the length of the axis. Then, the shape is added or subtracted so that the left argument's sign is flipped.

This implementation inherits all argument extensions from Take. The two middle lines are used to support right argument scalar rank extension and the SHARP APL short left argument extension. If Take does not have these extensions then they have no effect and can be removed.

External links

Lessons

Documentation

APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=Drop&oldid=9182’