# Without

(Redirected from Set Difference)
 `~`

Without (`~`), Set Difference, Excluding, or Less, is a dyadic set function which computes the set difference of the two vector arguments. It shares the glyph `~` with the monadic function Not.

## Examples

Both arguments of Without is usually restricted to vectors. Unlike sets in the mathematical sense, duplicate elements are allowed in both sides, and Without is usually implemented as "left argument filtered by the absence in the right argument" `(~X∊Y)/X`. This preserves the order and multiplicity in the left argument. Both arguments can be nested arrays.

```      'HELLO'~'GOODBYE'
HLL
A←'THIS' 'AND' 'THAT'
A~'TH' 'AND'
┌────┬────┐
│THIS│THAT│
└────┴────┘
```

## Extension

Some dialects allow Without to work on major cells:

Try it online!

```      X←4 2⍴'AABBCCCC'
Y←3 2⍴'AABBAA'
X~Y
CC
CC
```

Others can easily define such a function:

Try it online!

```      X←4 2⍴'AABBCCCC'
Y←3 2⍴'AABBAA'
Without←{⍺⌿⍨~(⍳≢⍺)∊⍺⍳⍵}
X Without Y
CC
CC
```
Works in: Dyalog APL