# Circular

(Redirected from Circle)
 ○

Circular (○), or Circle Function, is a dyadic scalar function, which is essentially a collection of related monadic functions. Circular encompasses trigonometric functions, hyperbolic functions, and a few relationships between them. On some implementations with complex numbers, Circular also includes functions to decompose and assemble a complex number. It shares the glyph ○ with the monadic arithmetic function Pi Times.

## Design

The Circular function, as found in today's APL implementations, was designed by Gene McDonnell, based on three things:[1]

• Ken Iverson stating that a concise programming language must group together related monadic functions as a dyadic function that takes a "controlling parameter" as left argument to select specific function.
• The sine, tangent, hyperbolic sine, and hyperbolic tangent are odd functions.
• No better symbol could be found for circular functions than the circle itself.

## Examples

Most APL implementations agree on the following functions:

(-X)○Y X X○Y
0 ${\displaystyle {\sqrt {1-Y^{2}}}}$
${\displaystyle \sin ^{-1}{Y}}$ 1 ${\displaystyle \sin {Y}}$
${\displaystyle \cos ^{-1}{Y}}$ 2 ${\displaystyle \cos {Y}}$
${\displaystyle \tan ^{-1}{Y}}$ 3 ${\displaystyle \tan {Y}}$
${\displaystyle {\sqrt {Y^{2}-1}}}$ 4 ${\displaystyle {\sqrt {1+Y^{2}}}}$
${\displaystyle \sinh ^{-1}{Y}}$ 5 ${\displaystyle \sinh {Y}}$
${\displaystyle \cosh ^{-1}{Y}}$ 6 ${\displaystyle \cosh {Y}}$
${\displaystyle \tanh ^{-1}{Y}}$ 7 ${\displaystyle \tanh {Y}}$

The following shows the values of sine, cosine, and tangent at ${\displaystyle 0,{\frac {\pi }{2}},\pi }$. Note that zeros are not exact and ${\displaystyle \tan {\frac {\pi }{2}}}$ does not signal DOMAIN ERROR because of limited precision of ${\displaystyle \pi }$.

      ⎕PP←5
'sin' 'cos' 'tan',1 2 3∘.○ ○0 0.5 1
sin  0 1           1.2246E¯16
cos  1 6.1232E¯17 ¯1
tan  0 1.6331E16  ¯1.2246E¯16

Works in: Dyalog APL

0○Y and 4○Y/¯4○Y reflect the identities ${\displaystyle \sin ^{2}{Y}+\cos ^{2}{Y}=1}$ and ${\displaystyle \cosh ^{2}{Y}-\sinh ^{2}{Y}=1}$ respectively. In APL code, 0○Y is equivalent to 1○¯2○Y and 2○¯1○Y, 4○Y is equivalent to 6○¯5○Y, and ¯4○Y is equivalent to 5○¯6○Y.

      0○¯0.9 ¯0.3 0 0.3 0.9
0.43589 0.95394 1 0.95394 0.43589
1○¯2○¯0.9 ¯0.3 0 0.3 0.9
0.43589 0.95394 1 0.95394 0.43589
2○¯1○¯0.9 ¯0.3 0 0.3 0.9
0.43589 0.95394 1 0.95394 0.43589

4○¯10 ¯1 0 1 10
10.05 1.4142 1 1.4142 10.05
6○¯5○¯10 ¯1 0 1 10
10.05 1.4142 1 1.4142 10.05

¯4○1 3 10
0 2.8284 9.9499
5○¯6○1 3 10
0 2.8284 9.9499


On implementations with complex number support, ¯4○Y is modified to ${\displaystyle (Y+1){\sqrt {\frac {Y-1}{Y+1}}}}$ so that it agrees with 5○¯6○Y for complex numbers.

As a mnemonic, the functions for even X are even functions, and those for odd X are odd functions. Also, X○Y and (-X)○Y are inverses of each other.

### Functions added with complex number support

Extensions with complex numbers are as follows:

(-X)○Y X X○Y
${\displaystyle -{\sqrt {-1-Y^{2}}}}$ 8 ${\displaystyle {\sqrt {-1-Y^{2}}}}$
Y unchanged 9 real part of Y
conjugate of Y 10 magnitude of Y
complex ${\displaystyle Y}$ (${\displaystyle iY}$) 11 imaginary part of Y
${\displaystyle e^{iY}}$ 12 phase of Y

The left arguments 9 and 11 extract the real and imaginary parts (the Cartesian coordinates on the complex plane), while 10 and 12 extract the magnitude and angle (the polar coordinates). The negative counterparts can be used to assemble a single complex number from the Cartesian or polar coordinates.

      ⎕←mat←9 11∘.○1J2 3J¯4 ¯5J¯6 ⍝ first row is real, second row is imag
1  3 ¯5
2 ¯4 ¯6
¯9 ¯11+.○mat
1J2 3J¯4 ¯5J¯6

⎕←mat←10 12∘.○1J2 3J¯4 ¯5J¯6 ⍝ first row is length, second row is angle
2.2361  5       7.8102
1.1071 ¯0.9273 ¯2.2655
¯10 ¯12×.○mat
1J2 3J¯4 ¯5J¯6

Works in: Dyalog APL

J has separate built-in functions for these operations: Real/Imag +. (Cartesian decomposition), Length/Angle *. (polar decomposition), Complex j. (Cartesian assembly), and Polar r. (polar assembly). Note that, unlike the APL version above, +. and *. create a trailing axis of length 2.

      ]mat =: +. 1j2 3j_4 _5j_6
1  2
3 _4
_5 _6
j./"1 mat
1j2 3j_4 _5j_6

]mat =: *. 1j2 3j_4 _5j_6
2.23607   1.10715
5 _0.927295
7.81025  _2.26553
r./"1 mat
1j2 3j_4 _5j_6

Works in: J

## References

1. McDonnell, Gene. The Story of ○. Recreational APL. APL Quote-Quad, Volume 8, Number 2, 1977-12.