Equal to: Difference between revisions

From APL Wiki
Jump to navigation Jump to search
m (Text replacement - " ⊢( *[^∘])" to " ⎕←$1")
m (Text replacement - "http://help.dyalog.com" to "https://help.dyalog.com")
Line 67: Line 67:
=== Documentation ===
=== Documentation ===


* [http://help.dyalog.com/latest/index.htm#Language/Primitive%20Functions/Equal.htm Dyalog]
* [https://help.dyalog.com/latest/index.htm#Language/Primitive%20Functions/Equal.htm Dyalog]
* [http://microapl.com/apl_help/ch_020_020_310.htm APLX]
* [http://microapl.com/apl_help/ch_020_020_310.htm APLX]
* J [https://www.jsoftware.com/help/dictionary/d000.htm Dictionary], [https://code.jsoftware.com/wiki/Vocabulary/eq#dyadic NuVoc]
* J [https://www.jsoftware.com/help/dictionary/d000.htm Dictionary], [https://code.jsoftware.com/wiki/Vocabulary/eq#dyadic NuVoc]
{{APL built-ins}}[[Category:Primitive functions]][[Category:Comparison functions]]
{{APL built-ins}}[[Category:Primitive functions]][[Category:Comparison functions]]

Revision as of 14:23, 14 July 2020

=

Equal to (=) is a comparison function which tests whether argument elements are tolerantly equal to each other: it returns 1 if the elements being compared match and 0 if they do not. It is the negation of Not Equal to (≠).

APL's = differs from the usage of in traditional mathematical notation by having an implied Iverson bracket. Thus, i=j is APL is equivalent to or (Kronecker delta) in mathematics.

Examples

Equal to compares arrays one element at a time, returning 1 when elements match and 0 when they do not. 

      3 2 1 = 1 2 3
0 1 0
      '321' = '123'
0 1 0
      3j2 2j2 1j2 = 2j2
0 1 0

It is subject to comparison tolerance: floating-point numbers which are very close together are considered equal, even though they are slightly different: 

      ⎕CT
1E¯14
      x ← 1 + (⎕CT×0.6)ׯ2 ¯1 0 1 2     ⍝ Numbers close to 1
      1 - x                             ⍝ Nonzero difference
1.199040867E¯14 5.995204333E¯15 0 ¯5.995204333E¯15 ¯1.199040867E¯14
      1 = x                             ⍝ Close but different values are equal
0 1 1 1 0
      1 {⎕CT←0⋄⍺=⍵} x                   ⍝ Overriding ⎕CT within a dfn
0 0 1 0 0

In a nested APL, Equal to is pervasive, and compares all simple scalars found in a nested array. 

      ⎕←n ← ((2 1)0)(1 0 3)(2 2⍴4 0)
┌───────┬─────┬───┐
│┌───┬─┐│1 0 3│4 0│
││2 1│0││     │4 0│
│└───┴─┘│     │   │
└───────┴─────┴───┘
      0 = n
┌───────┬─────┬───┐
│┌───┬─┐│0 1 0│0 1│
││0 0│1││     │0 1│
│└───┴─┘│     │   │
└───────┴─────┴───┘

In a flat array language such as J, it instead compares Boxes directly, since they are the elements of a boxed array. 

   (<'string') = 'which';'is';'string';'?'
0 0 1 0

Boolean function

Main article: Boolean function

When the arguments to Equal to are Boolean, it is the Logical biconditional function, or the negation of the xor function (which is Not Equal to restricted to Boolean arguments):

= 0 1
0 1 0
1 0 1

In the context of logic, it can be read as if and only if. This function is also known as xnor or the Kronecker delta.

Reduction with = is the same as reduction with xor (≠), but inverted if the number of reduced elements is even. The left and right identity element for Boolean = is 1.

External links

Documentation

APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=Equal_to&oldid=5119’