Range

… ...

Range (…, ...) or Sequence is a dyadic primitive function which creates a vector of consecutive integers based on the start and end values given by its arguments. It serves as an index origin-agnostic alternative to Index Generator for creating a range of numbers. Range is currently implemented in NARS2000 (using the digraph ..), Extended Dyalog APL, and dzaima/APL.

Basic usage

If both arguments are scalar integers, Range creates the consecutive range between the two arguments inclusive. If the left argument is greater than the right argument, the result becomes a decreasing sequence.

      3…8
3 4 5 6 7 8
      4…4
4
      5…¯5
5 4 3 2 1 0 ¯1 ¯2 ¯3 ¯4 ¯5

Works in: NARS2000, Extended Dyalog APL, dzaima/APL

It should be noted that, since the exact definition of Range has never been standardised, a different implementation might as well choose to return ⍬ or even throw a DOMAIN ERROR for X…Y when X>Y.

Extensions

NARS2000 supports step size and multi-dimensional range (giving the result similar to multi-dimensional Index Generator):

      3 2..10  ⍝ Start, step, and end values
3 5 7 9
      (⊂3 4)..6  ⍝ Two start values, so the result is two-dimensional and nested
┌───┬───┬───┐
│3 4│3 5│3 6│
├───┼───┼───┤
│4 4│4 5│4 6│
├───┼───┼───┤
│5 4│5 5│5 6│
├───┼───┼───┤
│6 4│6 5│6 6│
└───┴───┴───┘
      (6 7)2..2  ⍝ Two start values with step size; the sign of step size is ignored
┌───┬───┬───┐
│6 7│6 5│6 3│
├───┼───┼───┤
│4 7│4 5│4 3│
├───┼───┼───┤
│2 7│2 5│2 3│
└───┴───┴───┘

Works in: NARS2000

In Extended Dyalog APL, the extension is focused on making it easier to produce integer or character vector constants:

      1…10 20…100 80…0
1 2 3 4 5 6 7 8 9 10 20 30 40 50 60 70 80 90 100 80 60 40 20 0
      'a'…'zA'…'Z'
abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ

Works in: Extended Dyalog APL

External links

Documentation

• NARS2000