Power (function)

This page describes the dyadic function. For the monadic function that uses $e$ as a base, see Exponential. For the iteration operator, see Power (operator).

*

Power (*) is a dyadic scalar function that computes the exponentiation function of the two arguments, so that X*Y is X raised to the power Y. Power shares the glyph * with the monadic arithmetic function Exponential.

Examples

      2*¯1 0 1 2 3 4 5
0.5 1 2 4 8 16 32

A common technique is to choose sign based on a Boolean array:

      ¯1*1 0 0 1 0
¯1 1 1 ¯1 1

Properties

For positive integer Y, X*Y equals the product of Y copies of X. When Y is 0, X*Y equals 1, possibly except when X is also 0 (since zero to the power of zero is undefined in mathematics).

      3*5
243 
      ×/5⍴3
243
      1 2 3*0
1 1 1

Negating the exponent (right argument) gives the reciprocal of the return value.

      (2*¯4)=÷2*4
1

If the exponent is the reciprocal of some number n, the result is the n-th root of the base. For example, a right argument of ÷2 gives the square root.

      3*2
9
      9*÷2
3

Power has two inverses, Root and Logarithm:

      2*3
8
      2⍟8
3
      3√8
2

External links

Documentation

• Dyalog
• APLX
• J Dictionary, NuVoc
• BQN