At: Difference between revisions

From APL Wiki
Jump to navigation Jump to search
(correction for bools)
Line 2: Line 2:


== Description ==
== Description ==
At takes two operator arguments, and it has many overloads based on the types of its arguments.
At takes two operands, each of which can be an [[array]] or [[function]], with varying effect:
A call to At is of the form <source lang=apl inline>X(f@g)Y</source> where <source lang=apl inline>X</source> is optional.  
A call to At is of the form <source lang=apl inline>X(f@g)Y</source> where <source lang=apl inline>X</source> is optional.  
* <source lang=apl inline>g</source>  specifies the indices of the right argument that should be modified.
* <source lang=apl inline>g</source>  specifies the indices of the right argument that should be modified.
** '''Function''': Must apply to <source lang=apl inline>Y</source> , and return a boolean array with ones at positions that should be modified.
** '''Function''': Must apply monadically to <source lang=apl inline>Y</source>, and return a boolean array of the same shape as <source lang=apl inline>Y</source>, with ones at positions that should be amended.
** '''Array''': Specifies the indices directly. If this is a scalar, it is repeated as necessary.
** '''Array''': A [[vector]] (or [[scalar]]) of [[cell]] indices (of equal lengths) to amend. If the same index appears multiple times, the last amendment overrules any previous ones, meaning that amendments are not stacked. This is in contrast to [[modified assignment]] where multiple specifications of the same parts of the array will be processed sequentially.
* <source lang=apl inline>f</source> specifies what happens to the elements at those positions.
* <source lang=apl inline>f</source> specifies what happens to the elements at those positions.
** '''Function''': Applies to all the selected elements at once. If <source lang=apl inline>X</source> is given, then it is bound to this function (<source lang=apl inline>X∘f</source> ).
** '''Function''': Is applied once on an array whose [[major cell]]s are the selected cells. If <source lang=apl inline>X</source> is present, then it is bound to <source lang=apl inline>f</source> so <source lang=apl inline>X f@g Y</source> is equivalent to <source lang=apl inline>X∘f@g Y</source>.
** '''Array''': Replaces the selected elements.
** '''Array''': Replaces the selected elements and must either have the same shape as the array whose major cells are the selected cells, or be a scalar, which then replaces all selected cells.
Each possible [[derived function]] can be applied [[monadic]]ally or [[dyadic]]ally, except if the left operand (<source lang=apl inline>f</source>) is an array, in which case, only the monadic derived function is defined.


== Examples ==
== Examples ==

Revision as of 09:52, 27 April 2022

@

At (@) is a primitive dyadic operator that is similar to J and K's Amend in functionality. In Dyalog APL, At handles a subset of the cases of the Under operator that pertain to modifying elements at specific positions in an array.

Description

At takes two operands, each of which can be an array or function, with varying effect: A call to At is of the form X(f@g)Y where X is optional.

  • g specifies the indices of the right argument that should be modified.
    • Function: Must apply monadically to Y, and return a boolean array of the same shape as Y, with ones at positions that should be amended.
    • Array: A vector (or scalar) of cell indices (of equal lengths) to amend. If the same index appears multiple times, the last amendment overrules any previous ones, meaning that amendments are not stacked. This is in contrast to modified assignment where multiple specifications of the same parts of the array will be processed sequentially.
  • f specifies what happens to the elements at those positions.
    • Function: Is applied once on an array whose major cells are the selected cells. If X is present, then it is bound to f so X f@g Y is equivalent to X∘f@g Y.
    • Array: Replaces the selected elements and must either have the same shape as the array whose major cells are the selected cells, or be a scalar, which then replaces all selected cells.

Each possible derived function can be applied monadically or dyadically, except if the left operand (f) is an array, in which case, only the monadic derived function is defined.

Examples

      ⍝ Simple replacement
      (1 2 3@4 5 6)7 5 4 10 3 6 9 2 1 8
7 5 4 1 2 3 9 2 1 8
      (0@2 4) 1 2 3 4 5
1 0 3 0 5
      ⍝ f is a function
      10 (×@2 4) 1 2 3 4 5
1 20 3 40 5
      (÷@2 4) 1 2 3 4 5
1 0.5 3 0.25 5
      ⍝ g is a function
      '*'@(2∘|) 1 2 3 4 5  ⍝ Boolean selection 1 0 1 0 1
* 2 * 4 *
      ⍝ f and g are functions
      10 (×@(≤∘3)) 3 1 4 1 5
30 10 4 10 5
      ⌽@(2∘|) 1 2 3 4 5  ⍝ Reversal of sub-array 1 3 5
5 2 3 4 1

See Also

Under

External Links

Lessons

APL Cultivation

Documentation

Publications

Prefix friendly @ by Aaron Hsu and Roger Hui


APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=At&oldid=8451’