Partitioned Enclose

⊂

Partitioned Enclose (⊂) is a dyadic function which splits its right argument into differently sized pieces as determined by the non-negative integer left argument.

On a vector right argument, the corresponding element in the left argument indicates how many divisions to begin there:

      1 0 1 0 0 0 0⊂'HiEarth'
┌──┬─────┐
│Hi│Earth│
└──┴─────┘

Works in: Dyalog APL

Empty divisions can be inserted by beginning more than 1 division at a particular index:

      2 0 3 0 0 0 0⊂'HiEarth'
┌┬──┬┬┬─────┐
││Hi│││Earth│
└┴──┴┴┴─────┘

Additional trailing empty divisions are created by adding an additional division count corresponding to the index beyond the end of the right argument:

      1 0 1 0 0 0 0 1⊂'HiEarth'
┌──┬─────┬┐
│Hi│Earth││
└──┴─────┴┘

Partitioned Enclose allows a simple definition of a split-into-lengths function:

Try it online!

      Split←{⍵ ⊂⍨ ⍸⍣¯1 +\ ¯1↓1,⍺}
      3 3 4 Split 'HowAreYou?'
┌───┬───┬────┐
│How│Are│You?│
└───┴───┴────┘

Works in: Extended Dyalog APL

External links

Tutorials

• APL Cultivation

Documentation

• Dyalog