# Conway's Game of Life

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to navigation Jump to search

Conway's Game of Life is a well-known cellular automaton in which each generation of a population "evolves" from the previous one according to a set of predefined rules. The Game of Life is defined on an infinite Boolean grid, but usually only finite patterns, where all 1 values fit in a finite Boolean matrix, are studied. Because it involves interactions between adjacent elements of the matrix, and can take advantage of APL's convenient and fast Boolean handling, implementing the Game of Life is a popular activity for APLers. APL implementations have appeared in the APL Quote-Quad since 1971, a year after the rules of the Game of Life were first published. More recently, it is sometimes seen as a use case for the Stencil operator, which provides a concise way to work on three-by-three neighborhoods as used by the Game of Life.

A famous video by John Scholes[1] explains the following Dyalog APL implementation step by step. The implementation takes advantage of nested arrays and the Outer Product to produce many copies of the argument array. It finds adjacent elements by rotating the original array, causing elements at the edge to wrap around (giving a torus geometry).

```      life ← {⊃1 ⍵ ∨.∧ 3 4 = +/ +⌿ ¯1 0 1 ∘.⊖ ¯1 0 1 ⌽¨ ⊂⍵}
```

This implementation is also explained in its own article.

The Game of Life is often credited with introducing programmers to APL: Aaron Hsu[2] and Jay Foad[3] state that Scholes' video was their first introduction to APL, and Scholes himself says he became intrigued with the language in 1971 after hearing that a new language would allow the Xerox Sigma 9 to implement the Game of Life in a single line.[4][5]

## Historical implementations

First published in October 1970 by Martin Gardner in Scientific American[6], Conway's Game of Life quickly became a popular target of APL implementation. Jean Jacques Duby's 7-line interactive implementation appeared in APL Quote Quad exactly a year later.[7] Duby's tradfn takes as input a list of coordinates of live cells and displays subsequent states until no live cells remain or the user stops it; it was shown along with an pattern evolving into a beehive. The next state is computed one element at a time, so that the function makes little use of APL's array capabilities. The function was followed by a 9-line implementation in February 1972[8], both a 6-line and a 4-line implementation in June 1972[9], and an 8-line APL.SV implementation in 1974.[10] The last three implementations used more efficient strategies involving Rotate, indexing with an array index, or Take to obtain the neighbors of every array element at once.

The tradition of one-liner Game of Life implementations was firmly established by Eugene McDonnell's "Life: Nasty, Brutish, and Short", presented at APL88.[11] In addition to a survey of the Quote-Quad implementations listed above, McDonnell cites a 1984 IBM PC Tech Journal article which compared the expressiveness of various programming languages using the Game of Life as a benchmark. While the article presented favorably, Donald McIntyre wrote to the journal to complain about its verbosity, and present some logical simplifications. Like previous implementations, McIntyre's solution computes each of the eight neighbor arrays for the original state separately. McDonnell instead used SHARP APL's Rank operator to apply multiple rotations separately in a single step, and showed that the same could be done with APL2's Each operator. He first presented versions using two eight-element rotations vectors, and then showed how Don Knuth's Metafont implementation decomposed the sum into horizontal and vertical components and transferred this idea to APL, resulting in two 23-token implementations:

```⍝ SHARP APL
lf:((2×+⌿¯1 0 1⊖⍤0 2+⌿¯1 0 1⌽⍤0 2 ⍵)-⍵)∊5 6 7
⍝ APL2
lfe:((2×+⌿⊃¯1 0 1⊖¨+⌿¯1 0 1⌽¨⊂⍵)-⍵)∊5 6 7
```

McDonnell also described how future language features, such as the Commute operator and a tesselation operator related to Cut and the much later Stencil, might reduce this to as few as 11 tokens (one of which is a long list of integers), or to 9 tokens when using a pre-defined vector of matrices.

Cliff Reiter's 2005 article "Time(r) for the Game of Life"[12] studies the performance of several J implementations, including both methods based on Cut and one by Ewart Shaw more similar to McDonnell's Rotate-based strategies, finding the latter to be much faster. He also includes a survey of APL-family Life implementations since "Life: Nasty, Brutish, and Short".

John Scholes published a video in which he explains his own implementation of Life, the same as the function `Life` above, in 2009.[1] Scholes' function resembles McDonnell's APL2 implementation in its use of three-element vertical and horizontal rotation vectors, but uses Inner Product and Outer Product rather than Each as well as a different arithmetic scheme.

When introducing the Stencil operator in Dyalog APL 16.0, Roger Hui presented several Game of Life implementations using the new primitive.[13] These included Jay Foad's function `{3=s-⍵∧4=s←{+/,⍵}⌺3 3⊢⍵}`, translated from Arthur Whitney's K implementation `{3=s-x&4=s:2(+-1+/':)/x}`.[14]

Conway's Game of Life featured as one of the problems in the APL Code Golf Autumn Tournament, an event jointly run by Dyalog Ltd. and Optima Systems Ltd. In a follow-up Dyalog webinar, Adám Brudzewsky presented both the game and one of the winning 17-character solutions (`{≢⍸⍵}⌺3 3∊¨3+0,¨⊢`) in detail.[15]