Function-operator overloading

In APL syntax, function-operator overloading (archaic epithet: schizophrenia) is the practice of using a single glyph for both a primitive function and a primitive operator, which is then characterised as a hybrid primitive. Dialects with this feature include Dyalog APL, NARS2000, A+, GNU APL, and previously APL+Win. Most commonly it refers to one of the slash glyphs /⌿\⍀ (for example, / is both Replicate and Reduce), and dialects APL2 and APLX, which define Replicate and Expand to be operators, don't use it. Assignment may also be handled in a similar manner because ordinary assignment has the form of a dyadic function while modified assignment works like a monadic operator applied dyadically. Overloading may apply only to the glyphs themselves, or to their values and derivations as well: for example, in Dyalog APL the assignments r←/ and even r←/[3] cause r to exhibit overloading.

Occurrence

The following glyphs may be subject to function-operator overloading:

Glyph	Function	Operator
/	Replicate	Reduce
⌿
\	Expand	Scan
⍀
←	Assignment	Modified assignment

This form of overloading relies on the fact that an expression like a / b can be disambiguated based on whether a is a function or not: if so, / should be an operator. This assumption is violated when function trains are part of the syntax, because a train such as = / + could be interpreted either as the two-train (=/) +, Equals reduction atop Plus, or as a three train Equals Compress Plus. No interpretation can always give the result the user wants, but dialects with overloading always choose the first interpretation, in which the overloaded value is treated as an operator.

Function-operator overloading works by checking to the left of a potential function or operator to see if it is a function. This includes derived functions: for instance, the snippet -⍨/ is treated as a reduction with operand -⍨. In A+, only a small set of scalar dyadic functions can be used as operands to Reduce and Scan, and the language simply checks whether these glyphs appear immediately to the left of the slash. Thus, parenthesizing or assigning a name to these functions will cause overloading resolution to fail, resulting in a valence error.

Mitigation

The Atop operator provides a way to obtain the other interpretation: ⊢⍤/ is identical to / as a function, but forces the function-operator overloading to be resolved in favor of a function because there is a dyadic operator to its left. When the Atop operator is not available, Beside or Commute can be used instead, but they require an extra set of parentheses. Alternatively, the function behaviour can be forced by encapsulating the hybrid primitive in a dfn.

      (2=2 1) / (2+2 1)  ⍝ Desired result
4
      2 (= / +) 2 1      ⍝ / is treated as an operator: unwanted here
0
      2 (= ⊢⍤/ +) 2 1    ⍝ Resolved with Atop
4
      2 (= (/∘⊢) +) 2 1  ⍝ Resolved with Compose
4
      2 (= (/⍨⍨) +) 2 1  ⍝ Resolved with Commute
4
      2 (= {⍺/⍵} +) 2 1  ⍝ Resolved with dfn
4

Works in: Dyalog APL, with version 18.0 for Atop

None of the above techniques are possible in APL+Win, so system functions ⎕REPL and ⎕COMPRESS are provided instead. APL+Win previously allowed parenthesising a hybrid (for example (/)) to force function interpretation, although this is disabled when the evolution level is set to maximise APL2-compatibility.

External links

• GNU APL: Design Decisions — APL symbols that can be functions or operators
• Dyalog APL: Function Trains — Binding Strengths