Simple examples: Difference between revisions

=== Indices of multiple elements ===

<code class="apl">∊</code> gives us a mask for elements (characters) in the left argument that are members of the right argument:

       'mississippi'∊'sp'

0 0 1 1 0 1 1 0 1 1 0

<code class="apl">⍸</code> gives us the indices where true (1):

       ⍸'mississippi'∊'sp'

3 4 6 7 9 10

We can combine this into an anonymous infix (dyadic) function:

       'mississippi' (⍸∊) 'sp'

3 4 6 7 9 10

{{Works in|[[Dyalog APL]], [[NARS2000]], [[dzaima/APL]]}}

=== Parenthesis nesting level ===

First we compare all characters to the opening and closing characters;

       '()'∘.='plus(square(a),plus(square(b),times(2,plus(a,b)))'

0 0 0 0 1 0 0 0 0 0 0 1 0 0 0 0 0 0 0 1 0 0 0 0 0 0 1 0 0 0 0 0 0 0 0 1 0 0 0 0 0 0 1 0 0 0 0 0 0

0 0 0 0 0 0 0 0 0 0 0 0 0 1 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 1 1

An opening increases the current level, while a closing decreases, so we convert this to ''changes'' (or ''deltas'') by subtracting the bottom row from the top row:

       -⌿'()'∘.='plus(square(a),plus(square(b),times(2,plus(a,b)))'

0 0 0 0 1 0 0 0 0 0 0 1 0 ¯1 0 0 0 0 0 1 0 0 0 0 0 0 1 0 ¯1 0 0 0 0 0 0 1 0 0 0 0 0 0 1 0 0 0 ¯1 ¯1 ¯1

The running sum is what we're looking for:

       +\-⌿'()'∘.='plus(square(a),plus(square(b),times(2,plus(a,b)))'

0 0 0 0 1 1 1 1 1 1 1 2 2 1 1 1 1 1 1 2 2 2 2 2 2 2 3 3 2 2 2 2 2 2 2 3 3 3 3 3 3 3 4 4 4 4 3 2 1

{{Works in|all APLs}}

{{APL programming language}}