Unique: Difference between revisions

 `∪` `↑`

Unique (`∪`, `↑`), or Nub, is a monadic set function which removes duplicate major cells from an array. It returns only the distinct cells (those which do not match an earlier distinct cell) in the order they appeared in the array.

Examples

When called on the string "Mississippi", Unique keeps the first three letters and a later "p", but removes all subsequent occurrences. <syntaxhighlight lang=apl>

```     ∪ 'Mississippi'
```

Misp </source> It works on nested arrays as well: <syntaxhighlight lang=apl>

```     ∪ v←'CAT' 'DOG' 'CAT' 'DUCK' 'DOG' 'DUCK'
```

┌───┬───┬────┐ │CAT│DOG│DUCK│ └───┴───┴────┘ </source> In some languages, such as J and Dyalog APL 17.0 and later, Unique applies to the major cells of an array, including those with rank greater than 1: <syntaxhighlight lang=apl>

```     ⎕←x ← (⍳10)∘.∨2 3 6
```

1 1 1 2 1 2 1 3 3 2 1 2 1 1 1 2 3 6 1 1 1 2 1 2 1 3 3 2 1 2

```     ∪x
```

1 1 1 2 1 2 1 3 3 2 3 6 </source>

Definition

Unique returns an array which is composed of some major cells of its argument; thus the shape of the result is identical to the shape of the argument in all but the leading axis, and less than or equal to it in that axis. A scalar argument is subject to scalar rank extension; the result for a scalar will always be its ravel. Often the argument of Unique is required to be a vector, but the result is still computed in the way described here.

To construct the Unique of an array, the major cells are considered in order of increasing index. Each cell is included if it does not match any cell which was already included.

The array matching is subject to tolerant comparison. In the intolerant case, that is, when equality is transitive, a cell is included if and only if it does not match any other cell which appears earlier in the array. That's because all the discarded duplicate cells must have matched an earlier included cell; if equality is transitive then a cell which matches the duplicate would also match the earlier cell.

Tolerant comparison

The following example shows why we must be careful about how cells are matched when tolerant comparison is involved. Here we produce a vector in which the first and second elements match, as do the second and third, but the first and third elements do not! Unique produces an array which contains an element matching every element of the original array, but a less careful definition (for example, excluding every element which matches an earlier one) would fail to satisfy this property. <syntaxhighlight lang=apl>

```     ⎕CT←1e¯14
⎕PP←18 ⍝ Print all digits
⎕←x←1+⎕CT×0 0.6 1.2
```

1 1.000000000000006 1.000000000000012

```     ⍳⍨x    ⍝ Each element equal to the previous
```

1 1 2

```     ∪x     ⍝ Includes the last element!
```

1 1.000000000000012

```     x∊∪x   ⍝ Every element matches some unique element
```

1 1 1

```     x∊1↑x  ⍝ ...which wouldn't happen if the last were excluded
```

1 1 0 </source>

Works in: Dyalog APL

History

The function Nub was proposed in 1978 by Iverson as one of a collection of set functions (including Union, Intersection, and Difference) with the symbol <syntaxhighlight lang=apl inline>∪</source> and definition <syntaxhighlight lang=apl inline>∪w</source> ${\displaystyle \Leftrightarrow }$ <syntaxhighlight lang=apl inline>((⍳⍴w)=w⍳w)/w←,w</source>.[1] It was implemented as part of STSC's NARS in 1981 with the name Unique and the same definition, except that the argument was restricted to be a vector or scalar.[2] Later APLs such as Dyalog APL generally adopted this version of the primitive, and it is featured in the ISO/IEC 13751:2001 standard. Dyalog extended Unique to higher-rank arrays in Dyalog APL 17.0, following the much earlier extension made by J.

Iverson continued to refine his definition of Nub. He included it in his Rationalized APL specification with no changes in 1983, but modified it to work on major cells (thus aligning it with leading axis theory) in his 1987 A Dictionary of APL. Iverson's dictionary also changed the symbol for Nub to <syntaxhighlight lang=apl inline>↑</source>, added the functions Nub Sieve (<syntaxhighlight lang=apl inline>≠</source>) and Nub in (<syntaxhighlight lang=apl inline>=</source>), and defined Nub in terms of Nub Sieve. These definitions were adopted by IPSA in the SHARP APL successor SAX. J uses similar definitions: its Nub-related functions are Nub (<syntaxhighlight lang=j inline>~.</source>), Nub Sieve (<syntaxhighlight lang=j inline>~:</source>), and Self-classify (<syntaxhighlight lang=j inline>=</source>). However, Self-classify is indicated as deprecated in J's NuVoc because its result can be much larger than its argument.

A+ does not include Unique or any related functions, but K's function range (`?`) gives the unique elements of a list argument. In later versions it is called "distinct" or "unique". While APLs allow a scalar argument (scalar rank extension), K gives a RANK ERROR if the argument is not a list.

APL model

For vectors the following implementation based on Union can be used. It repeatedly adds cells of the argument to an accumulated unique vector <syntaxhighlight lang=apl inline>u</source>, using Union so that duplicate cells are never added. <syntaxhighlight lang=apl> VecUnique ← {

```   u ← 0↑⍵
u ⊣ {u∪←⍵}⍤¯1 ⊢1/⍵
```

} </source>

Works in: Dyalog APL

The accumulation above resembles a reduction—in fact, it is a reverse insertion. The following implementation written with Reduce works for simple vectors in nested APLs because reduction is equivalent to insertion followed by Enclose on such vectors: <syntaxhighlight lang=apl> VecUnique ← {⊃∪⍨/⌽⍵} </source>

It can be modified to obtain a full model for Unique by enclosing enough times, and converting scalars to vectors with Replicate at the end: <syntaxhighlight lang=apl> Unique ← {1/↑↑⌽∪/⌽⊂∘⊂⍤¯1⊢⍵} </source>

Works in: Dyalog APL

While the model <syntaxhighlight lang=apl inline>{((⍳≢⍵)=(⍵⍳⍵))⌿⍵}</source>, based on Nub Sieve, is often described as an implementation of Unique, it does not correctly handle tolerant comparison.[3] A correct implementation of Nub Sieve could be used to implement Unique, but writing such an implementation is no easier than implementing Unique directly.

Properties

The first major cell of a non-empty argument to Unique is included in the result, since there are no earlier cells for it to match. It follows that the result of Unique is empty only if the argument was empty.

Every major cell in the argument to Unique matches at least one cell in its result: if a cell didn't match any cells in the Unique, then it would have been included itself. A cell may match multiple cells if it matches both but they do not match each other.