Replicate: Difference between revisions

From APL Wiki
Jump to navigation Jump to search
No edit summary
Line 59: Line 59:
Compress was described in [[A Programming Language]], which used the notation <math>/</math> and <math>//</math> for it. It was included in [[APL\360]] changing the doubled slash to a barred slash <source lang=apl inline>⌿</source>, and continued to be included in APLs essentially unchanged until 1980.
Compress was described in [[A Programming Language]], which used the notation <math>/</math> and <math>//</math> for it. It was included in [[APL\360]] changing the doubled slash to a barred slash <source lang=apl inline>⌿</source>, and continued to be included in APLs essentially unchanged until 1980.


In 1980, [[Bob Bernecky]] introduced the extension Replicate to [[SHARP APL]]: he allowed an operand (since SHARP's Replicate is an operator) consisting of non-negative integers rather than just [[Boolean]]s to indicate the number of times to copy.<ref>[[Bob Bernecky|Bernecky, Bob]]. SATN-34: Replication. [[IPSA]]. 1980-08-15.</ref> This extension was quickly implemented in [[NARS]], along with further extensions: a similar change to [[Expand]], and the extension allowing negative integers to indicate [[fill elements]]. Both extensions were quickly adopted by the APL community, and were included in new languages such as [[Dyalog APL]] and [[APL2]], and later the [[ISO/IEC 13751:2001]] standard.
In 1980, [[Bob Bernecky]] introduced the extension Replicate to [[SHARP APL]]: he allowed an operand (since SHARP's Replicate is an operator) consisting of non-negative integers rather than just [[Boolean]]s to indicate the number of times to copy.<ref>[[Bob Bernecky|Bernecky, Bob]]. SATN-34: Replication. [[IPSA]]. 1980-08-15.</ref> This extension was implemented in [[NARS]] in 1981, along with further extensions: a similar change to [[Expand]], and the extension allowing negative integers to indicate [[fill elements]]. Both extensions were quickly adopted by the APL community, and were included in new languages such as [[Dyalog APL]] and [[APL2]], and later the [[ISO/IEC 13751:2001]] standard.


== External Links ==
== External Links ==

Revision as of 10:31, 13 March 2020

/

Replicate (/, ), or Copy (#) in J, is a dyadic function or monadic operator that copies each element of the right argument a given number of times, ordering the copies along a specified axis. Typically / is called Replicate while is called "Replicate First" or an equivalent. Replicate is a widely-accepted extension of the function Compress, which requires the number of copies to be Boolean: each element is either retained (1 copy) or discarded (0 copies). Replicate with a Boolean left argument or operand may still be called "Compress".

Replicate is usually associated with Expand (\), and the two functions are related to Mask and Mesh. It is also closely related to the Indices function. It shares a glyph with Reduce even though Replicate is naturally a function and Reduce must be an operator. This incongruity is occasionally resolved by making Replicate an operator itself, and more often by function-operator overloading allowing both syntactic elements to coexist.

Outside of APL, filter typically provides the functionality of Compress, while Replicate has no common equivalent.

Examples

When used with a Boolean array (often called a "mask") on the left, Replicate is called Compress. It filters the right argument, returning only those elements which correspond to 1s in the provided mask.

      1 1 0 1 0 1 0 0 / 'compress'
cope

If the right argument is an array of indices generated by Iota, Replicate resembles the function Indices.

      1 1 0 0 1 / ⍳5
1 2 5

With an array of non-negative integers, Replicate copies each element of the right argument the corresponding number of times. As with Compress, these copies retain their original ordering, and the length of the result is the sum of the control array.

      0 3 0 0 2 0 1 0 2 / 'replicate'
eeeiiaee
      +/ 0 3 0 0 2 0 1 0 2
8
      ⍴ 0 3 0 0 2 0 1 0 2 / 'replicate'
8

A second extension introduced by NARS allows either positive or negative integers, where a negative number indicates that a fill element should be used instead of an element from the right argument. In this case the length of the result is the sum of the absolute value of the control array.

      0 2 ¯3 1 / ⍳4
2 2 0 0 0 4

Replicate works along a particular axis, which can be specified in languages with function axis and otherwise is the first axis for , and the last axis for / (except in A+, which uses / for the first-axis form and has no last-axis form).

      ⊢A ← 4 6⍴⎕A
ABCDEF
GHIJKL
MNOPQR
STUVWX
      1 0 0 4 0 2 / A
ADDDDFF
GJJJJLL
MPPPPRR
SVVVVXX
      0 2 1 1 ⌿ A
GHIJKL
GHIJKL
MNOPQR
STUVWX

Replicate usually allows scalar extension of the left argument, which results in every element being copied a fixed number of times.

      3 / 'replicate'
rrreeepppllliiicccaaattteee

History

Compress was described in A Programming Language, which used the notation and for it. It was included in APL\360 changing the doubled slash to a barred slash , and continued to be included in APLs essentially unchanged until 1980.

In 1980, Bob Bernecky introduced the extension Replicate to SHARP APL: he allowed an operand (since SHARP's Replicate is an operator) consisting of non-negative integers rather than just Booleans to indicate the number of times to copy.[1] This extension was implemented in NARS in 1981, along with further extensions: a similar change to Expand, and the extension allowing negative integers to indicate fill elements. Both extensions were quickly adopted by the APL community, and were included in new languages such as Dyalog APL and APL2, and later the ISO/IEC 13751:2001 standard.

External Links

Lessons

Documentation

References

  1. Bernecky, Bob. SATN-34: Replication. IPSA. 1980-08-15.


APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic ConjugateNegateSignumReciprocalMagnitudeExponentialNatural LogarithmFloorCeilingFactorialNotPi TimesRollTypeImaginarySquare Root
Dyadic AddSubtractTimesDivideResiduePowerLogarithmMinimumMaximumBinomialComparison functionsBoolean functions (And, Or, Nand, Nor) ∙ GCDLCMCircularComplexRoot
Non-Scalar
Structural ShapeReshapeTallyDepthRavelEnlistTableCatenateReverseRotateTransposeRazeMixSplitEncloseNestCut (K)PairLinkPartitioned EnclosePartition
Selection FirstPickTakeDropUniqueIdentityStopSelectReplicateExpandSet functions (IntersectionUnionWithout) ∙ Bracket indexingIndexCartesian ProductSort
Selector Index generatorGradeIndex OfInterval IndexIndicesDealPrefix and suffix vectors
Computational MatchNot MatchMembershipFindNub SieveEncodeDecodeMatrix InverseMatrix DivideFormatExecuteMaterialiseRange
Operators Monadic EachCommuteConstantReplicateExpandReduceWindowed ReduceScanOuter ProductKeyI-BeamSpawnFunction axis
Dyadic BindCompositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner ProductDeterminantPowerAtUnderRankDepthVariantStencilCutDirect definition (operator)
Quad names Index originComparison toleranceMigration levelAtomic vector