Partitioned Enclose: Difference between revisions

== Basic functionality ==

In the simplest case, and on a vector right argument, the corresponding element in the left argument indicates where '''divisions''' begin:

       1 0 1 0 0 0 0⊂'HiEarth'

┌──┬─────┐

│Hi│Earth│

└──┴─────┘

{{Works in|[[Dyalog APL]], [[Extended Dyalog APL]]}}

== Non-Boolean left argument ==

Almost all dialects restrict the left argument to provide only the above functionality. However, the left argument can be interpreted as a count of how many partitions begin with a particular position:

       2 0 3 0 0 0 0⊂'HiEarth'

┌┬──┬┬┬─────┐

││Hi│││Earth│

└┴──┴┴┴─────┘

== Short left argument ==

The dialects that support this extension also allow omission of trailing zeros, which is useful if the partitioning vector is generated by [[indices#Inverse|where's inverse]]:

       ⍸⍣¯1⊢1 1 3 3 3

2 0 3

││Hi│││Earth│

└┴──┴┴┴─────┘

== Long left argument ==

Additional trailing empty divisions are created by adding an additional division count corresponding to the position beyond the end of the right argument:

       1 0 1 0 0 0 0 1⊂'HiEarth'

┌──┬─────┬┐

│Hi│Earth││

└──┴─────┴┘

== Split into lengths ==

This above extensions allow a simple definition of a split-into-lengths function:

[https://tio.run/##SyzI0U2pTMzJT9dNrShJzUtJTfn/qLdP/VHf1GBXvZRHbROqNQxtH3UufNS7S/NRx/JHvWvAnC1AvhVQEVABkJWSVqJg8Ki7BSKQkllcABSshQgAjdEAUuHB6uquZal5JerqGurqwanFxZn5eQFFmSABBXX1FHV1zUddi4EKnSOBvLS8YqCA@v/ggpzMEpAjHvVuVXjU1fSod4XCo94dj3oXH1pvqKAdowCkHrVNNtQB2ff/v7GCsYKJAliTgrpHfrljUWpkfqm9OgA Try it online!]

       Split←{⍵ ⊂⍨ ⍸⍣¯1 +\ ¯1↓1,⍺}

       3 3 4 Split 'HowAreYou?'

│How│Are│You?│

└───┴───┴────┘

== See also ==

* [[Partition]]