# Difference between revisions of "Function composition"

Jump to navigation Jump to search

Function composition refers to the "gluing" together of two or more functions using a dyadic operator or a train such that the functions are applied to the argument(s) as normal, but in a particular pattern specific to the used operator. The term function composition comes from traditional mathematics where it is used for a function ${\displaystyle h(x)=f(g(x))}$ when written as ${\displaystyle h(x)=(f\circ g)(x)}$. APL generalises this idea to dyadic functions, allowing various patterns of application in addition to the simple application of one monadic function to the result of another monadic function.

## Common compositions

Reverse Compose and Beside treat their arguments in an asymmetric way. Their patterns can be visualised as follows:

Reverse Compose Beside

Atop and Over treat their arguments in a symmetric way. Their patterns can be visualised as follows:

Atop Over

The patterns represented by trains, the 2-train Atop and the 3-train Fork, can be visualised as follows:

2-train 3-train

The `∘` operator (in this context called Bind) and the 3-train can also be used with constant arrays, then treating the arrays (`A`) as constant functions, much as if they were used as operands to the Constant operator (`A⍨`):

Bind 3-train

### Summary of rules

The above compositions can be summarised as follows:

`  (f⍛g  ) ⍵` ${\displaystyle \Leftrightarrow }$ `(  f ⍵) g      ⍵ `
`⍺ (f⍛g  ) ⍵` ${\displaystyle \Leftrightarrow }$ `(  f ⍺) g      ⍵ `
`  (  g∘h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (  h ⍵)`
`⍺ (  g∘h) ⍵` ${\displaystyle \Leftrightarrow }$ `   ⍺    g (  h ⍵)`

`  (  g⍤h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (  h ⍵)`
`⍺ (  g⍤h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (⍺ h ⍵)`
`  (  g⍥h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (  h ⍵)`
`⍺ (  g⍥h) ⍵` ${\displaystyle \Leftrightarrow }$ `(  h ⍺) g (  h ⍵)`

`    (g h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (  h ⍵)`
`⍺   (g h) ⍵` ${\displaystyle \Leftrightarrow }$ `        g (⍺ h ⍵)`
`  (f g h) ⍵` ${\displaystyle \Leftrightarrow }$ `(  f ⍵) g (  h ⍵)`
`⍺ (f g h) ⍵` ${\displaystyle \Leftrightarrow }$ `(⍺ f ⍵) g (⍺ h ⍵)`

`  (A∘g  ) ⍵` ${\displaystyle \Leftrightarrow }$ `   A    g      ⍵ `
`  (  g∘A) ⍵` ${\displaystyle \Leftrightarrow }$ `   ⍵    g      A `
`  (A g h) ⍵` ${\displaystyle \Leftrightarrow }$ `   A    g (  h ⍵)`
`⍺ (A g h) ⍵` ${\displaystyle \Leftrightarrow }$ `   A    g (⍺ h ⍵)`

## Additional compositions

Additional compositions are possible, even without using an argument more than once or applying a function to its own result. However, most of these are rather trivial shuffled-around versions of the above three. For example, one could define an operator identical to Atop, only that it applies the right operand to the result of the left operand, that is `{⍵⍵ ⍺ ⍺⍺ ⍵}`.

When Dyalog added Atop and Over, it was with the reasoning that these were the only compositions where the leftmost function acted as the "root" function in the evaluation tree, while the arguments were used each on their respective sides of the constituent functions:

Of note here is `f⍨∘g⍨` which is equivalent to — although with swapped operands — Reverse-compose `⍛` (also called Before), and the mirrored version of Beside `∘` (also known as Compose and After), because it is the only such variation that has been implemented, namely in dzaima/APL and Extended Dyalog APL.

A compositional operator that isn't just a shuffled around version of the basic three, is one that applies one operand between the other operand's dyadic result and the result of that other operand's result when swapped: `{(⍵ ⍵⍵ ⍺) ⍺⍺ (⍺ ⍵⍵ ⍵)}`. This operator can for example be used to implement three-way comparison:

Try it online!

```      S ← {(⍵ ⍵⍵ ⍺) ⍺⍺ (⍺ ⍵⍵ ⍵)}
cmp ← -S≤
2 cmp 3
¯1
3 cmp 3
0
4 cmp 3
1
```