# Depth (operator): Difference between revisions

 `⍥`

Depth (`⍥`) is a primitive dyadic operator which applies its left operand function to sub-arrays of its arguments specified by its right operand array. It appears in Extended Dyalog APL, dzaima/APL, J (as `L:`), and BQN (as `⚇`).

## Introduction

The Depth operator is a generalisation of the Each operator (as `¨`). While Each switches application from being directly on array arguments, to be on their elements, Depth allows exact specification of the depth level of each argument that the function is applied to.

Depth is closely related to Rank (`⍤`), but while Rank specifies the rank of the final arguments of the left operand function, Depth specifies the depth of the final arguments of the left operand function.

For all arguments, when applied with a non-negative right depth specification (the right operand), and also with negative depth specification even when the arguments are ragged (of non-uniform depth), `f⍥p⊢Y` is equivalent to `f¨¨``¨¨Y` and `X f⍥p⊢Y` is equivalent to `(⊂⊂``⊂⊂X)f¨¨``¨¨⊂⊂``⊂⊂Y` where "`xx``xx`" indicates some number of repetitions of the function or operator `x`.

## Depth specification

The right operand specifies the depth of sub-arrays to which the left operand function is applied as follows: For left argument `⍺` and right argument `⍵`,

```   ⍤    c   ⍝ Depth-c sub-arrays of ⍵ (monadic) or both arguments (dyadic)
⍤  b c   ⍝ Depth-b sub-arrays of ⍺ and depth-c sub-arrays of ⍵ (dyadic)
⍤a b c   ⍝ Depth-a sub-arrays of ⍵ (monadic), depth-b sub-arrays of ⍺ and depth-c sub-arrays of ⍵ (dyadic)
```

A non-negative right operand specifies the depth of the final arguments to which the function applies. Therefore, application with a depth specification of `0` causes the function to be called only on simple scalars, thus implementing pervasion for any given function.

A negative right operand specifies complementary depth, i.e. the number of levels to descend into before applying the operand. Negative depth can also be thought of as depth specification relative to the overall depth of the argument array. Thus, a depth specification of `¯1` is equivalent to application with Each and in general, a depth specification of `-k` is equivalent to application with `k` Eaches.

Since a depth specification greater than the depth of the argument array means to apply the function to the whole array, `(⌊/⍬)` or `∞`, depending on the implementation, is "depth infinity" and always specifies the whole argument array. However, in practice, any large number, for example 9, is sufficient for most uses.

## Examples

Reverse each element in a ragged depth-3D array (note that all member vectors are reversed, despite that their individual structures vary):

```      ⌽⍥¯1⊢('abc' 'cdef') 'ghi'  ⍝ equivalent to ⌽¨('abc' 'cdef') 'ghi'
┌──────────┬───┐
│┌────┬───┐│ihg│
││cdef│abc││   │
│└────┴───┘│   │
└──────────┴───┘
```

Reverse each simple vector in a ragged depth-3D array (note that each simple vector is reversed, even though the amount of penetration, into the entire array, varies):

```      ⌽⍥1⊢('abc' 'cdef') 'ghi'
┌──────────┬───┐
│┌───┬────┐│ihg│
││cba│fedc││   │
│└───┴────┘│   │
└──────────┴───┘
```

Concatenate a constant prefix to each element:

```        '; ',⍥1⊢'abc' 'cdef' 'ghi'  ⍝ equivalent to (⊂'; '),¨'abc' 'cdef' 'ghi'
┌─────┬──────┬─────┐
│; abc│; cdef│; ghi│
└─────┴──────┴─────┘
```

Pair up the elements on the left with each element of each element on the right.

```      'xy',⍥¯1⍥¯1⊢('ab' 'cd')('AB' 'CD')  ⍝ equivalent to (⊂'xy'),¨¨('ab' 'cd')('AB' 'CD')
┌─────────┬─────────┐
│┌───┬───┐│┌───┬───┐│
││xab│ycd│││xAB│yCD││
│└───┴───┘│└───┴───┘│
└─────────┴─────────┘
```