# Beside: Difference between revisions

 `∘`

Beside (`∘`), Compose or After is a primitive operator. It shares the glyph `∘` with Bind. Called dyadically with function operands `f` and `g`, it uses `g` monadically to pre-processes the right argument before applying `f` to the given left argument and pre-processed right argument. Called monadically with operands `f` and `g`, it applies `f` to the result of applying `g` to the argument.

In usage, `X f∘g Y` is equivalent to `X f g Y`, and `f∘g Y` is equivalent to `f g Y`. Thus, beside can be defined as the dop `{⍺←⊢ ⋄ ⍺ ⍺⍺ ⍵⍵ ⍵}`.

## Examples

When used monadically, `f∘g` behaves the same as an atop:

```      -∘÷ 2
¯0.5
⍝ same as
-(÷2)
¯0.5
```

When used dyadically, `f∘g` forms a dyadic hook:

```      'oy'≡∘⌽'yo'
1
⍝ same as
'oy'≡⌽'yo'
1
```

When used monadically with Commute, `f∘g` forms a monadic hook:

```      ≡∘⌽⍨'UwU'
1
⍝ same as this, because operators are left-associative, unlike functions which are right-associative
(≡∘⌽)⍨'UwU'
1
⍝ same as
'UwU'≡⌽'UwU'
1
```