John Scholes' Conway's Game of Life

John Scholes' Conway's Game of Life video is perhaps the most famous APL video. In it, John Scholes explains his own implementation of Conway's Game of Life in Dyalog APL, where he, one step at a time, develops the following dfn: <syntaxhighlight lang=apl>

     life ← {⊃1 ⍵ ∨.∧ 3 4 = +/ +⌿ ¯1 0 1 ∘.⊖ ¯1 0 1 ⌽¨ ⊂⍵}

</source>

Scholes also published notes on the Game of Life, including alternate implementations, in his dfns workspace. The workspace includes a function which differs in a few small details. <syntaxhighlight lang=apl>

     Life←{↑1 ⍵∨.∧3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂⍵}

</source>

In this page we will break down the function <syntaxhighlight lang=apl inline>Life</source> to see how each part operates. If you're completely new to APL, you probably won't understand all of it right away—consider also reading some Simple examples or APL introductions. However, you should be able to follow the general ideas. Bear in mind that APL evaluates expressions from right to left unless you use parentheses.

The code here is written for Dyalog APL. It also works in ngn/apl, and other nested array languages allow similar implementations: see #Translations.

In 2021, Conor Hoekstra remade the video with additional explanations.

The Glider

One interesting pattern that occurs in Life is a Glider: <syntaxhighlight lang=apl>

     glider←3 3⍴1 1 1 1 0 0 0 1 0
     glider

1 1 1 1 0 0 0 1 0 </source>

To see how the Glider evolves over the generations, we need to give it some space to move around. The Game of Life takes place on an infinite two-dimensional grid, but that might be a bit large for our computer! Let's start the Glider off in the bottom right-hand corner of a 10 x 10 grid: <syntaxhighlight lang=apl>

     grid←¯10 ¯10↑glider
     grid

0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 1 1 0 0 0 0 0 0 0 1 0 0 0 0 0 0 0 0 0 0 1 0 </source>

After one generation the pattern becomes: <syntaxhighlight lang=apl>

     Life grid

0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 0 0 0 0 0 0 0 0 1 1 0 0 0 0 0 0 0 0 1 0 1 0 0 0 0 0 0 0 0 0 0 </source>

The Glider has slightly changed shape and also moved up and to the left.

Visualising it

To make the pattern easier to see, we can use indexing to place a <syntaxhighlight lang=apl inline>⌺</source> symbol where there's a cell and a <syntaxhighlight lang=apl inline>·</source> otherwise, for example (note that <syntaxhighlight lang=apl inline>⎕IO</source> is Index Origin): <syntaxhighlight lang=apl>

     Show←{'·⌺'[⎕IO+⍵]}
     Show grid

·········· ·········· ·········· ·········· ·········· ·········· ·········· ·······⌺⌺⌺ ·······⌺·· ········⌺· </source>

Here's how the Glider evolves over the first ten generations, computed using the Power operator for iteration: <syntaxhighlight lang=apl>

     Show¨{Life⍣⍵⊢grid}¨0,⍳9

┌──────────┬──────────┬──────────┬──────────┬──────────┬──────────┬──────────┬──────────┬──────────┬──────────┐ │··········│··········│··········│··········│··········│··········│··········│··········│··········│··········│ │··········│··········│··········│··········│··········│··········│··········│··········│··········│··········│ │··········│··········│··········│··········│··········│··········│··········│··········│··········│··········│ │··········│··········│··········│··········│··········│··········│··········│··········│··········│··········│ │··········│··········│··········│··········│··········│··········│··········│··········│··········│······⌺···│ │··········│··········│··········│··········│··········│·······⌺··│······⌺⌺··│······⌺⌺··│·····⌺⌺⌺··│·····⌺⌺···│ │··········│········⌺·│·······⌺⌺·│·······⌺⌺·│······⌺⌺⌺·│······⌺⌺··│······⌺·⌺·│·····⌺⌺···│·····⌺····│·····⌺·⌺··│ │·······⌺⌺⌺│·······⌺⌺·│·······⌺·⌺│······⌺⌺··│······⌺···│······⌺·⌺·│······⌺···│·······⌺··│······⌺···│··········│ │·······⌺··│·······⌺·⌺│·······⌺··│········⌺·│·······⌺··│··········│··········│··········│··········│··········│ │········⌺·│··········│··········│··········│··········│··········│··········│··········│··········│··········│ └──────────┴──────────┴──────────┴──────────┴──────────┴──────────┴──────────┴──────────┴──────────┴──────────┘ </source>

How it works

To compute a new generation in the Game of Life we first need to find out how many neighbours each live cell has. To keep things simple let's consider the following 5-by-5 grid:

<syntaxhighlight lang=apl>

     currentGeneration←5 5⍴0 0 0 0 0 0 0 1 1 0 0 1 1 0 0 0 0 1 0 0
     currentGeneration

0 0 0 0 0 0 0 1 1 0 0 1 1 0 0 0 0 1 0 0 0 0 0 0 0 </source>

Rotation

If we rotate each row of the grid one place left by using APL's Rotate function <syntaxhighlight lang=apl inline>⌽</source>, each element is replaced by its right-hand neighbour. In other words, the new grid will have a 1 for all cells whose right-hand neighbour was 1:

<syntaxhighlight lang=apl>

     1⌽currentGeneration

0 0 0 0 0 0 1 1 0 0 1 1 0 0 0 0 1 0 0 0 0 0 0 0 0 </source>

Similarly we can rotate right to find the left-hand neighbour by using <syntaxhighlight lang=apl inline>¯1⌽currentGeneration</source>. By using APL's Outer Product operator <syntaxhighlight lang=apl inline>∘.</source> together with the Rotate function we can get a set of three grids containing the left-hand neighbour, the original grid, and the right-hand neighbour:

<syntaxhighlight lang=apl>

     ¯1 0 1∘.⌽⊂currentGeneration

┌─────────┬─────────┬─────────┐ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ │0 0 0 1 1│0 0 1 1 0│0 1 1 0 0│ │0 0 1 1 0│0 1 1 0 0│1 1 0 0 0│ │0 0 0 1 0│0 0 1 0 0│0 1 0 0 0│ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ └─────────┴─────────┴─────────┘ </source>

Here <syntaxhighlight lang=apl inline>currentGeneration</source> must be enclosed before applying the outer product so that it is treated as a single element rather than rotating each of its Boolean elements (which would have no effect).

Extending to two dimensions

Now we can use a similar trick but rotate up and down by using APL's First Axis Rotate function <syntaxhighlight lang=apl inline>⊖</source>. Used with an Outer Product this gives us a series of 9 grids:

<syntaxhighlight lang=apl>

    ¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┬─────────┬─────────┐ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ │0 0 0 1 1│0 0 1 1 0│0 1 1 0 0│ │0 0 1 1 0│0 1 1 0 0│1 1 0 0 0│ │0 0 0 1 0│0 0 1 0 0│0 1 0 0 0│ ├─────────┼─────────┼─────────┤ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ │0 0 0 1 1│0 0 1 1 0│0 1 1 0 0│ │0 0 1 1 0│0 1 1 0 0│1 1 0 0 0│ │0 0 0 1 0│0 0 1 0 0│0 1 0 0 0│ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ ├─────────┼─────────┼─────────┤ │0 0 0 1 1│0 0 1 1 0│0 1 1 0 0│ │0 0 1 1 0│0 1 1 0 0│1 1 0 0 0│ │0 0 0 1 0│0 0 1 0 0│0 1 0 0 0│ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ │0 0 0 0 0│0 0 0 0 0│0 0 0 0 0│ └─────────┴─────────┴─────────┘ </source>

The grid in the centre is our original grid, and the others give the neighbours above, below, left, right and diagonally.

Summing it up

Now we can find out how many neighbours each cell in the original grid has by summing (Plus Reduce) the corresponding elements in each of the 9 grids. We sum all the grids at once by ravelling the shape <syntaxhighlight lang=apl inline>3 3</source> matrix of grids to obtain a 9-element vector; otherwise Reduce would only allow us to sum rows or columns. Here APL's representation of Booleans as numbers is advantageous, since otherwise counting the number of true values would require converting them to numbers or using conditional logic. For a live cell the sum is 1 more than the number of neighbours—for example, a 4 in the result means a cell has three neighbours. For a dead cell the result is just the number of neighbours:

<syntaxhighlight lang=apl>

     +/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 1 2 2 1│ │1 3 4 3 1│ │1 4 5 4 1│ │1 3 3 2 0│ │0 1 1 1 0│ └─────────┘ </source>

For a cell to exist in the next generation, one of two rules must be met:

• Any live cell with two neighbours lives, unchanged, to the next generation
• Any cell, live or dead, with exactly three neighbours is live in the next generation

This means that all cells which might be live in the next generation will have a sum of 3 (from the first rule) or 3 or 4 (from the second rule).

So we're interested in cells with a sum of 3 or 4. We can find these cells with a simple application of Equal to, relying on pervasion and scalar extension to distribute the data properly. The result of the last step was a scalar containing one grid; when paired with the vector <syntaxhighlight lang=apl inline>3 4</source> it is extended to give two grids. Within each grid 3 and 4 are compared with every element by scalar extension again. If the right argument were a flat array rather than being enclosed, we could obtain a similar, but flat, result using another Outer Product.

<syntaxhighlight lang=apl>

    3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┬─────────┐ │0 0 0 0 0│0 0 0 0 0│ │0 1 0 1 0│0 0 1 0 0│ │0 0 0 0 0│0 1 0 1 0│ │0 1 1 0 0│0 0 0 0 0│ │0 0 0 0 0│0 0 0 0 0│ └─────────┴─────────┘ </source>

The next step is best understood by first considering the two scores 4 and 3 separately.

(a) A score of 4 corresponds either to a live cell with three neighbours or a dead cell with four neighbours. Only in the former case do we get a cell in the next generation - i.e. we get a cell if the score is 4 and the cell is currently live. Here we're using APL's And function, <syntaxhighlight lang=apl inline>∧</source> <syntaxhighlight lang=apl>

   (⊂currentGeneration)∧4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 0 0 0 0│ │0 0 1 0 0│ │0 1 0 0 0│ │0 0 0 0 0│ │0 0 0 0 0│ └─────────┘ </source>

(b) A score of three corresponds either to a live cell with two neighbours or a dead cell with three neighbours. In either case we get a cell in the next generation: <syntaxhighlight lang=apl>

     3=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 0 0 0 0│ │0 1 0 1 0│ │0 0 0 0 0│ │0 1 1 0 0│ │0 0 0 0 0│ └─────────┘ </source>

We can write this slightly redundantly by and-ing with 1 (meaning "and the cell is alive or dead") for reasons which will become apparent shortly: <syntaxhighlight lang=apl>

     1∧3=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 0 0 0 0│ │0 1 0 1 0│ │0 0 0 0 0│ │0 1 1 0 0│ │0 0 0 0 0│ └─────────┘ </source>

So the next step is to say that a cell is live if either test (a) or test (b) is met. We need to use APL's Or function, <syntaxhighlight lang=apl inline>∨</source>. We could write this rather long-windedly as: <syntaxhighlight lang=apl>

    (1∧3=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration)∨(⊂currentGeneration)∧4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 0 0 0 0│ │0 1 1 1 0│ │0 1 0 0 0│ │0 1 1 0 0│ │0 0 0 0 0│ └─────────┘ </source>

Refactoring

But we can take advantage of APL's Inner Product operator to do the and operations of each test and then or the result - the <syntaxhighlight lang=apl inline>∨.∧</source> in the following:

<syntaxhighlight lang=apl>

    1 currentGeneration∨.∧3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂currentGeneration

┌─────────┐ │0 0 0 0 0│ │0 1 1 1 0│ │0 1 0 0 0│ │0 1 1 0 0│ │0 0 0 0 0│ └─────────┘ </source>

The final expression ends with a bit of housekeeping using Mix (<syntaxhighlight lang=apl inline>↑</source>) to turn the result back into a simple array (it's currently nested).

Translations

GNU APL

In GNU APL the Inner Product <syntaxhighlight lang=apl inline>∨.∧</source> results in a twice-enclosed matrix, rather than once-enclosed as in Dyalog APL. This can be fixed either by mixing twice, or by using a reduction instead of an inner product. <syntaxhighlight lang=apl>

     Life←{↑↑1 ⍵∨.∧3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂⍵}
     Life←{↑∨/1 ⍵∧3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂⍵}

</source>

dzaima/APL

In dzaima/APL the reduction <syntaxhighlight lang=apl inline>+/</source> mixes its result, which defeats our use of scalar extension causing a LENGTH ERROR. Because the sum has only one (matrix) result, enclosing it corrects this issue. <syntaxhighlight lang=apl>

     Life←{↑1 ⍵∨.∧3 4=⊂+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂⍵}

</source> The computation of our example <syntaxhighlight lang=apl inline>grid</source> also fails, because dzaima's Take does not allow overtaking. Instead we can insert the glider into a matrix of zeros using structural Under: <syntaxhighlight lang=apl>

     grid ← ¯10 ¯10↑glider            ⍝ DomainError
     grid ← glider⍢(¯3 ¯3∘↑) 10 10⍴0  ⍝ This works

</source>

Ruby

Github user zverok has translated Scholes' dfn to Ruby by first creating an <syntaxhighlight lang=ruby inline>apl</source> module to implement parts of APL. The code is shown on Github and explained on zverok's blog.

Performance

Although it uses nested arrays to organize the computation, Scholes' Game of Life implementation can still be a fairly fast algorithm on medium and large matrices, competitive with straightforward C implementations. This is because the simple arrays stored in the outer nested array all have the same size as the argument. There are only nine of these arrays, so the overhead associated with nesting is constant and small. Until they are summed, these arrays are Boolean, allowing them to be stored in a packed representation and rotated quickly (Roger Hui states that the Game of Life motivated some improvements to Boolean functions in Dyalog 13.2 and 14.0). When adding them, recent versions of Dyalog APL use vector instructions, enabling many numbers to be added at once.

The following code times how long it takes to perform 1000 iterations of the Game of Life on a shape <syntaxhighlight lang=apl inline>1000 1000</source> array. This computation performs a billion cell updates, so the total time in seconds is equal to the time taken per update in nanoseconds. <syntaxhighlight lang=apl>

     )copy dfns cmpx
     b←1=?1e3 1e3⍴2
     1 cmpx 'Life⍣1000 ⊢b'

</source> The timings below were taken with various versions of Dyalog APL on an Intel Kaby Lake i7. The largest change appears in 17.0, when Boolean-integer addition was implemented using vector instructions (on this processor, AVX2).

Version	Time (s)
15.0	14.0
16.0	13.5
17.0	1.32
17.1	1.31
18.0 (pre-release)	0.75