Readability
Maintaining readability of APL can take a special effort. It is easy to write very dense code, and the mathematical look of APL can encourage usage of single-letter names. Since Phil Abrams used the term at the APL '73 conference,[1] APLers have traditionally used pornography to describe code that is hard to read, or uses unusual constructs. Alan Perlis countered that But as we all know, being people of the world, pornography thrives![2] Code golf often results in pornographic code.
Examples
Gilman & Rose
In APL ― An Interactive Approach, the authors describe the following code, which computes the correlation coefficient, as “almost pornographic”:
r←(+/x×y)÷((+/(x←x-(+/x)÷⍴x)*2)×+/(y←y-(+/y)÷⍴y)*2)×.5
By splitting the expression intro even a moderate number of pieces, a symmetry is revealed:
yVar←+/(y-(+/y)÷⍴y)*2 xVar←+/(x-(+/x)÷⍴x)*2 r←(+/x×y)÷(xVar×yVar)×0.5
This also avoids reusing variable names, and thus ensures that the code can be rerun from any point. The chosen additional variable names are still short, but quite indicative of what they signify (variance). Finally, the .5 is expanded to 0.5 which helps to clarify that this is a decimal number and not an inner product.
A more modern approach breaks out the symmetry into a utility function train, and uses leading axis theory combined with operators and reordering of terms to avoid parentheses (which would otherwise require a mental stack to understand). Finally, the correlation coefficient is defined as a stand-alone function, using inner product to combine summation with multiplication
Var←+/2*⍨⊢-+⌿÷≢ R←2×+.×÷×⍥Var r←x R y
Note that +⌿÷≢ is an idiom (common phrase) and is read as average by even moderately experienced APL programmers.
IBM
The idiom list included with APL2 includes the following entry:[3]
X←'line1',0⍴Y←'line2'⍝ Pornography. Combining two lines into one.
This was once a common technique before, even though it is prone to fail in where the value to the left of ,0⍴ isn't a vector, for example in the following example where X becomes a 1-element vector instead of the intended scalar:
X←'l',0⍴Y←'line2'
Y∘.=X
1
0
0
0
0
With the addition of Left (⊣) to the language, this type of hack became became entirely obsolete:
X←'line1' ⊣ Y←'line2'
The primitive leaves its left argument unmodified:
X←'l' ⊣ Y←'line2'
Y∘.=X
1 0 0 0 0
The Diamond statement separator (⋄) provides an alternative means of inlining multiple statements:
Y←'line2' ⋄ X←'line1'
Note that in all the above, Y is assigned first.
Morten Kromberg
Morten Kromberg asked one of his colleagues to “Please avoid this kind of pornography:”
ns(⍎container.⎕NS)←⍬
Avoiding the unusual modified assignment (using the 2-train ⍎⎕NS as modifying function) helps:
ns←ns container.(⍎⎕NS) ⍬
Finally, splitting the 2-train apart makes it even clearer:
ns←⍎ns container.⎕NS ⍬
A new namespace, with the original value of ns as name, is created inside container and the character representation '#.container.ns' is returned from ⎕NS to ⍎ which evaluates the name to a reference, that in turn replaces the previous value of ns. Note that ⎕NS returns fully qualified namespace path to the newly created namespace, and thus it doesn't matter in which namespace ⍎ is called.
Honeywell
Honeywell [4] used a more specific definition:
- In APL, pornography is defined informally as the dependence upon undefined evaluation order for the successful or correct evaluation of an APL statement.
This refers to things like
a←4 (a+3)×a
where it is undefined whether the initial value for a is used at all in the second line, yielding 12, or whether the second assignment is done before times gets its right argument, and thus the result is 9.
Similarly, in
i←2 (2 1⍴10 20)[i;i←1]
the evaluation order of the statements in the bracket indexing is undefined. If i is evaluated before i←1 then the result is 20, otherwise it is 10.
The Multics APL manual goes on to use the terms monstrosity and eyesore for code published in an APL newsletter, such as
Z[B+(C∧X∊D)/⍳⍴X;]+(24p' Y9 X9 ')[(C←(-≠\''''=X)∧A≤⍴D)/A←(D←'⍵⍺')⍳X;]
The manual suggests that this code should be split into the following expressions:
D←'⍵⍺' A←D⍳X C←(-≠\''''=X)∧A≤⍴D B←(C∧X∊D)/⍳⍴X Z[B;]←(24p' Y9 X9 ')[C/A;]
See also
References
- ↑ Abrams, Phil. Program Writing, Rewriting and Style. APL Conference 73. Canadian Printco Limited. 1973.
- ↑ Perlis, Alan. Almost Perfect Artifacts Improve only in Small Ways: APL is more French than English. APL '78.
- ↑ Cason, Stan. APL2 IDIOMS Library, Assignment Algorithms. IBM.
- ↑ Honeywell. Multics APL User's Guide (AK95-02), 3-16. December 1985.