ReplaceCharactersInString

Given a character vector V and a translate table consisting of two equal length character vectors T and S, replace all occurrencies in V of characters also in T with the corresponding character from S.

      (S,V)[(T,V)⍳V]                                   ⍝ V←CV; S←CV; T←CV; (⍴S)=⍴T

There are many ways of coding this some of which will be quicker in some APLs. The advantage here is that it is concise, memorable and returns a result directly rather than as a side effect.

Examples

      ⎕FX⍕2 1⍴'r←tv ReplaceCharsInString cv' 'r←((1⊃tv),cv)[((0⊃tv),cv)⍳cv]'
      'papa' 'lima'ReplaceCharsInString 'alpha papa lima'
illhi lili limi
      'one' 'two'ReplaceCharsInString'zero one two three four five'
zort two twt throo ftur fivo
      'two' 'one'ReplaceCharsInString'zero one two three four five'
zere ene one ohree feur five

== How not to do it! == If there is a common way to do this task that produces wrong or inconsistent results or does it relatively very inefficiently you can put it here But please be polite, moderate and considerate in your description

Conforming Variants

As square bracket indexing[] is deprecated in some quarters I give here a version that takes the same number of characters and about the same execution time that uses the index function ⌷ instead:

      (⊂(T,V)⍳V)⌷S,V

and another that uses pick ⊃ that's one character longer and perhaps marginally quicker:

      ((T,V)⍳V)⊃¨⊂S,V

All three variants can be enhanced by the doubling of the commas in the phrase to be rank independent in the text to be changed.

      ⎕FX⍕2 1⍴'r←tv ReplaceCharsInArray ca' 'r←(((0⊃tv),,ca)⍳ca)⊃¨⊂(1⊃tv),,ca'
      nums,'one' 'two' ReplaceCharsInArray' ',nums←2 3 5⍴'zero one  two  threefour five '
zero  zort
one   two
two   twt

three throo
four  ftur
five  fivo

There is many a related phrase which is speedier for the special case of a single replacement character. Here is one that is similarly direct which again could be specified using any if the three indexing techniques:

      (S,V)[1+(T≠V)×⍳⍴V]

== Specialities == Add special remarks for specific dialects here, for example the mentioning of a system function solving the problem goes here

Compatibility

Checked with: APL2, Dyalog, NARS2000, APLX APL+Win, - Add as many as you can/like

Test Cases

Replace "PhraseName" accordingly Show Hide test cases test cases

 Test;z;x;⎕IO
 ⎕IO←0
 ⎕FX⍕2 1⍴'r←tv ReplaceCharsInString cv' 'r←((1⊃tv),cv)[((0⊃tv),cv)⍳cv]'
⍝ ---- Start Test cases (do not delete this!)
 'illhi lili limi'≡'papa' 'lima'ReplaceCharsInString'alpha papa lima'
 'zort two twt throo ftur fivo'≡'one' 'two'ReplaceCharsInString'zero one two three four five'
 'zere ene one ohree feur five'≡'two' 'one'ReplaceCharsInString'zero one two three four five'
 z≡'' ''ReplaceCharsInString,z←,⎕CR'ReplaceCharsInString'        ⍝ empty translate table
 z≡'abc' 'abc'ReplaceCharsInString,z←,⎕CR'ReplaceCharsInString'  ⍝ in = out
 x≡'abc' 'def'ReplaceCharsInString,x←z~'abc'                     ⍝ none in target

Test my code, both Examples and Test Cases.

See also: ... Add proper Wiki names. The pages do not necessarily must exist. If they don't they will show up on WantedPages and that's just fine

Mentor: PhilLast

Tags are used to create a list automatically - see ListAllTags Tags: <AppropriateCamelCaseName> <Simpleword> Use "!" to avoid unwanted links for CamelCase names

CategoryPhrasesAll - CategoryPhraseCharacterManipulation